COP 3503 PROJECT 3 

INPUT FILES 

There are two kinds of files you will encounter for Project 3:
Recipe Files and Inventory Files. I will modify the rules to make it 
easier to parse (get rid of some options), though you may parse the
full version for extra credit. In what follows, I will give the 
restricted version so you will know what you must be able to handle.
For the most part, this involves forcing the XML file to follow certain
conventions. 

All these files will have the .xml extension, and will start with an XML
header that looks like this:

<?xml version=blah blah blah skip this stuff?>
<!DOCTYPE blah blah blah skip this stuff too>

After these two tags, you will get to the meat of the matter.
In what follows, I will use caps for CFG variables, and put literals
in quotes.  For example, the CFG productions
S -> "Hello " V ("!")*
V -> "Kitty" | "World"
produce the sentences
Hello Kitty
Hello Kitty!
Hello Kitty!!
etc.
and
Hello World
Hello World!
Hello World!!
Hello World!!!
etc.
I will use e for the empty string.

Here is the grammar with explanation.

START -> COOKBOOK | INVENTORY
INVENTORY -> "<inventory>" (INGREDIENT_LIST | EQUIPMENT_LIST)+ "</inventory>"

Recipe Files encode a cookbook, so COOKBOOK is the start symbol for
them, while inventory files consist of equipement and/or ingredient
lists, so INVENTORY will be the start symbol for them.

EQUIPMENT_LIST -> "<equipmentlist>" EQUIPS "</equipmentlist>" 
EQUIPS -> EQUIPMENT | EQUIPMENT EQUIPS

Equipment list is one or more pieces of equipment.

COOKBOOK -> "<cookbook>" (TITLE | e) S_OR_R_LIST "</cookbook>"

This means the cookbook may or may not have a title, followed by
a list of sections and/or recipes, but it always starts and ends 
with the tags "<cookbook>" and "</cookbook>".

TITLE -> "<title>" (R_CHAR)* "</title>
R_CHAR -> ALPHA | DIGIT | WHITESPACE | '_' | '"' | '/' | PUNCT
ALPHA -> alphabet characters
DIGIT -> numeric characters
WHITESPACE -> whitespace characters (space, tab, return)
PUNCT -> ',' | '.' | ':' | '(' | ')' | '!' | '@' | '#' | '$' | '%' | 
         '^' | '&' | '*' | '_' | '-' | '=' | '+' | '[' | ']' | '\' |
         '{' | '}' | '/' | '?' | '~' 

Note that '<' and '>' are NOT included in PUNCT

S_OR_R_LIST -> (SECTION | RECIPE) | (SECTION | RECIPE) S_OR_R_LIST

This means there must be at least one section or recipe, but there 
may be any number of them in any order.

SECTION -> "<section>" (TITLE | e) RECIPE_LIST "</section>"

So a section optionally has a title, followed by a recipe list.

RECIPE_LIST -> RECIPE | RECIPE RECIPE_LIST

Again, a recipe list must have at least one recipe, but maybe more.

RECIPE -> "<recipe>" TITLE INGREDIENT_LIST PREPARATION "</recipe>"

So a recipe is bookended with the <recipe>, </recipe> tags, with 
mandatory title, ingredient list, and preparation.

INGREDIENT_LIST -> "<ingredientlist>" INGREDIENTS "</ingredientlist>"
INGREDIENTS ->  INGREDIENT | INGREDIENT INGREDIENTS 

Here, I require there to be at least one ingredient in the list (the
dtd file does not). Again, the list is bookended with the proper tags.

INGREDIENT -> "<ingredient>" FOODITEM MODS "<ingredient>"
INGREDIENT -> "<ingredient>" QUANTITY FOODITEM MODS "<ingredient>"
INGREDIENT -> "<ingredient>" QUANTITY UNITS FOODITEM MODS  "<ingredient>"

There are three possibilities for a fooditem - it must have a name
describing the actual ingredient, it may have a quantity, and if it
has a quantity, it may also have units. I have also restricted the
order in which these must appear to be the "natural" order, and 
restricted the modifying text outside the tags to the end (so you can
have 3 cups greenbeans, washed and trimmed, but not washed and trimmed
greenbeans, 3 cups). 

MODS -> RCHAR*

This just lets the mods be pretty much any text that doesn't look like a tag.

FOODITEM -> "<fooditem>" RCHARS+ "</fooditem>"
QUANTITY -> "<quantity>" NUMBER "</quantity>"
UNITS -> "<units>" RCHARS+ "</units>"

We don't try to interpret what the food item or the units are here, but we
do require that the quantity be a number.

NUMBER -> INTEGER | FLOAT | FRACTION
INTEGER -> DIGIT+
FLOAT -> (INTEGER | e) "." (INTEGER)
FRACTION -> (INTEGER | e) " " INTEGER "/" INTEGER

We require a number to have one or more digits, optionally with decimal
point and fractional part, or optionally with fraction expressed as 
numerator/denominator. Handling fractions is OPTIONAL for the project.

PREPARATION -> "<preparation>" STEP_LIST "</preparation>" 
STEP_LIST -> STEP | STEP STEP_LIST
STEP -> "<step>" STEPTEXT "</step>" 
STEPTEXT -> RCHARS (EQUIPMENT (RCHARS | e))* 
EQUIPMENT -> "<equipment>" RCHARS "</equipment>"

Preparation now must be in the form of step. Each step must have some text
and optionally has equipment and more text.


START -> COOKBOOK | INVENTORY
INVENTORY -> "<inventory>" (INGREDIENT_LIST | EQUIPMENT_LIST)+ "</inventory>"
EQUIPMENT_LIST -> "<equipmentlist>" EQUIPS "</equipmentlist>" 
EQUIPS -> EQUIPMENT | EQUIPMENT EQUIPS
EQUIPMENT -> "<equipment>" RCHARS "</equipment>"
COOKBOOK -> "<cookbook>" (TITLE | e) S_OR_R_LIST "</cookbook>"
TITLE -> "<title>" (R_CHAR)* "</title>
S_OR_R_LIST -> (SECTION | RECIPE) | (SECTION | RECIPE) S_OR_R_LIST
SECTION -> "<section>" (TITLE | e) RECIPE_LIST "</section>"
RECIPE_LIST -> RECIPE | RECIPE RECIPE_LIST
RECIPE -> "<recipe>" TITLE INGREDIENT_LIST PREPARATION "</recipe>"
INGREDIENT_LIST -> "<ingredientlist>" INGREDIENTS "</ingredientlist>"
INGREDIENTS ->  INGREDIENT | INGREDIENT INGREDIENTS 
INGREDIENT -> "<ingredient>" FOODITEM MODS "<ingredient>"
INGREDIENT -> "<ingredient>" QUANTITY FOODITEM MODS "<ingredient>"
INGREDIENT -> "<ingredient>" QUANTITY UNITS FOODITEM MODS  "<ingredient>"
MODS -> RCHAR*
FOODITEM -> RCHARS+
QUANTITY -> NUMBER
UNITS -> RCHARS+
NUMBER -> INTEGER | FLOAT | FRACTION
INTEGER -> DIGIT+
FLOAT -> (INTEGER | e) "." (INTEGER)
FRACTION -> (INTEGER | e) " " INTEGER "/" INTEGER
PREPARATION -> "<preparation>" STEP_LIST "</preparation>" 
STEP_LIST -> STEP | STEP STEP_LIST
STEP -> "<step>" STEPTEXT "</step>" 
STEPTEXT -> RCHARS (EQUIPMENT (RCHARS | e))* 
R_CHAR -> ALPHA | DIGIT | WHITESPACE | '_' | '"' | '/' | PUNCT
ALPHA -> alphabet characters
DIGIT -> '0' | '1' | '2' | '3' | '4' | '5' | '6' | '7' | '8' | '9' | '0'
WHITESPACE -> whitespace characters (space, tab, return)
PUNCT -> ',' | '.' | ':' | '(' | ')' | '!' | '@' | '#' | '$' | '%' | 
         '^' | '&' | '*' | '_' | '-' | '=' | '+' | '[' | ']' | '\' |
         '{' | '}' | '/' | '?' | '~'